//+------------------------------------------------------------------+
//|                                 correlations - macd to price.mq4 |
//|                                                           mladen |
//|                                                                  |
//| Pearson correlation of MACD to price                             |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property indicator_buffers  1
#property indicator_color1   DeepSkyBlue
#property indicator_width1   2
#property indicator_maximum  1.1
#property indicator_minimum -1.1
#property indicator_level1   0
#property indicator_levelcolor DimGray

//
//
//
//
//

extern ENUM_TIMEFRAMES     TimeFrame            = PERIOD_CURRENT;
extern int                 CorrelationPeriod    = 14;
extern int                 MacdFastPeriod       = 12;
extern int                 MacdSlowPeriod       = 26;
extern ENUM_APPLIED_PRICE  MacdPrice            = PRICE_CLOSE;
extern ENUM_APPLIED_PRICE  Price                = PRICE_CLOSE;
extern int                 PriceSmoothPeriod    =  0;
extern int                 PriceSmoothPhase     =  0;
extern int                 PosCorrSmoothPeriod  =  0;
extern int                 PosCorrSmoothPhase   =  0;
extern bool                alertsOn             = true;
extern bool                alertsOnCurrent      = true;
extern bool                alertsMessage        = true;
extern bool                alertsSound          = false;
extern bool                alertsEmail          = false;
extern bool                alertsNotify         = false;
extern bool                Interpolate          = true;


double corr[];
double macd[];
double price[];
double trend[];
string indicatorFileName;
bool   returnBars;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   IndicatorBuffers(4);
   SetIndexBuffer(0,corr);
   SetIndexBuffer(1,macd);
   SetIndexBuffer(2,price);
   SetIndexBuffer(3,trend);
   
   indicatorFileName = WindowExpertName();
   returnBars        = TimeFrame==-99;
   TimeFrame         = MathMax(TimeFrame,_Period);
   IndicatorShortName(timeFrameToString(TimeFrame)+" correlations - macd to price");
   return(0);
}

//
//
//
//
//
int start()
{
   int counted_bars=IndicatorCounted();
   int i,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
           limit=MathMin(Bars-counted_bars,Bars-1);
           if (returnBars) { corr[0] = MathMin(limit+1,Bars-1); return(0); }

   //
   //
   //
   //
   //
   
   if (TimeFrame == Period())
   {
     for(i=limit;i>=0;i--)
     {
        macd[i]  = iMACD(NULL,0,MacdFastPeriod,MacdSlowPeriod,1,MacdPrice,MODE_MAIN,i);
        price[i] = iSmooth(iMA(NULL,0,1,0,MODE_SMA,Price,i),PriceSmoothPeriod,PriceSmoothPhase,i, 0);
        corr[i]  = iSmooth(iCorrelation(macd,price,CorrelationPeriod,i),PosCorrSmoothPeriod,PosCorrSmoothPhase,i,10);
        trend[i] = trend[i+1];
           if (corr[i]>0) trend[i] = 1;
           if (corr[i]<0) trend[i] =-1;
     }
     
     //
     //
     //
     //
     //
     
     if (alertsOn)
     {
       if (alertsOnCurrent)
            int whichBar = 0;
       else     whichBar = 1; int forBar = Bars-whichBar-1;
       if (trend[forBar] != trend[forBar-1])
       {
          if (trend[forBar] == 1) doAlert(whichBar,"crossed zero up");
          if (trend[forBar] ==-1) doAlert(whichBar,"crossed zero down");
       }         
     }
     return(0);
    }
    
    //
   //
   //
   //
   //
   
   limit = MathMax(limit,MathMin(Bars-1,iCustom(NULL,TimeFrame,indicatorFileName,-99,0,0)*TimeFrame/Period()));
   for (i=limit; i>=0; i--)
   {
      int y = iBarShift(NULL,TimeFrame,Time[i]);
         corr[i] = iCustom(NULL,TimeFrame,indicatorFileName,PERIOD_CURRENT,CorrelationPeriod,MacdFastPeriod,MacdSlowPeriod,MacdPrice,Price,PriceSmoothPeriod,PriceSmoothPhase,PosCorrSmoothPeriod,PosCorrSmoothPhase,alertsOn,alertsOnCurrent,alertsMessage,alertsSound,alertsEmail,alertsNotify,0,y);
         
         //
         //
         //
         //
         //
      
         if (!Interpolate || y==iBarShift(NULL,TimeFrame,Time[i-1])) continue;

         //
         //
         //
         //
         //

         datetime time = iTime(NULL,TimeFrame,y);
            for(int n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
            for(int k = 1; k < n; k++) corr[i+k] = corr[i] + (corr[i+n] - corr[i])*k/n;
                  
   }
return(0);
}

//+------------------------------------------------------------------
//|                                                                 
//+------------------------------------------------------------------
//
//
//
//
//

double iCorrelation(double& first[], double& second[], int length, int i)
{
   double sx  = 0;
   double sy  = 0;
   double sxy = 0;
   double sx2 = 0;
   double sy2 = 0;
            
   for (int k=0; k<length; k++)
   {
      double pricea = first[i+k];
      double priceb = second[i+k];
         sx += pricea; sx2 += pricea*pricea;
         sy += priceb; sy2 += priceb*priceb;
                       sxy += pricea*priceb;
   }
    
   double result  = 0;
   double divisor = MathSqrt(((sx2-(sx*sx)/length)*(sy2-(sy*sy)/length)));
      if (divisor != 0)
               result = (sxy - (sx*sy)/length)/divisor;
   return(result);
}

//+------------------------------------------------------------------
//|                                                                 
//+------------------------------------------------------------------
//
//
//
//
//

double wrk[][20];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iSmooth(double tprice, double length, double phase, int i, int s)
{
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   if (length <=1) return(tprice);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[0][k+s]=tprice; for(; k<10; k++) wrk[0][k+s]=0; return(tprice); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = tprice - wrk[r-1][bsmax+s];
      double del2   = tprice - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = tprice; else wrk[r][bsmax+s] = tprice - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = tprice; else wrk[r][bsmin+s] = tprice - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = tprice + alpha*(wrk[r-1][0+s]-tprice);
         wrk[r][1+s] = (tprice - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}

//
//
//
//
//

void doAlert(int forBar, string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
      if (previousAlert != doWhat || previousTime != Time[forBar]) {
          previousAlert  = doWhat;
          previousTime   = Time[forBar];

          //
          //
          //
          //
          //

          message =  StringConcatenate(timeFrameToString(Period())+" "+Symbol()," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," correlations - macd to price ",doWhat);
             if (alertsMessage) Alert(message);
             if (alertsEmail)   SendMail(StringConcatenate(Symbol(),"correlations - macd to price"),message);
             if (alertsNotify)  SendNotification(message);
             if (alertsSound)   PlaySound("alert2.wav");
      }
}

//-------------------------------------------------------------------
//
//-------------------------------------------------------------------
//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}