//------------------------------------------------------------------
#property link      "www.forex-tsd.com"
#property copyright "www.forex-tsd.com"
//------------------------------------------------------------------
#property indicator_separate_window
#property indicator_buffers    6
#property indicator_color1     LimeGreen
#property indicator_color2     LimeGreen
#property indicator_color3     DarkOrange
#property indicator_color4     DarkOrange
#property indicator_color5     DarkSlateGray
#property indicator_color6     Coral 
#property indicator_width2     2
#property indicator_width4     2
#property indicator_width5     2
#property indicator_width6     2
#property indicator_level1     0
#property indicator_levelcolor DarkGray

//
//
//
//
//

extern double Length       = 50;
extern double Phase        = 0;
extern bool   SmoothDouble = false;
extern double SignalLength = 21;
extern double SignalPhase  = 0;
extern bool   SignalDouble = false;

//
//
//
//
//

double cqs[];
double signal[];
double cqshuu[];
double cqshud[];
double cqshdd[];
double cqshdu[];
double diff[];
double slope[];

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//

int init()
{
   IndicatorBuffers(8);
   SetIndexBuffer(0,cqshuu); SetIndexStyle(0,DRAW_HISTOGRAM);
   SetIndexBuffer(1,cqshud); SetIndexStyle(1,DRAW_HISTOGRAM);
   SetIndexBuffer(2,cqshdd); SetIndexStyle(2,DRAW_HISTOGRAM);
   SetIndexBuffer(3,cqshdu); SetIndexStyle(3,DRAW_HISTOGRAM);
   SetIndexBuffer(4,cqs);
   SetIndexBuffer(5,signal);
   SetIndexBuffer(6,diff);
   SetIndexBuffer(7,slope);
   IndicatorShortName("ChandeQStick("+Length+")");
return(0);
}
int deinit() { return(0); }

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//

int start()
{
   int counted_bars=IndicatorCounted();
   int i,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);
         
   //
   //
   //
   //
   //
   
   for(i=limit; i>=0; i--) 
   {
      diff[i] = Close[i]-Open[i];
      if (diff[i] != 0)
           cqs[i] = iDSmooth(diff[i],Length,Phase,SmoothDouble,i,0);
      else cqs[i] = iDSmooth(0,      Length,Phase,SmoothDouble,i,0);
      cqshuu[i] = EMPTY_VALUE;
      cqshud[i] = EMPTY_VALUE;
      cqshdd[i] = EMPTY_VALUE;
      cqshdu[i] = EMPTY_VALUE;
      signal[i] = iDSmooth(cqs[i],SignalLength,SignalPhase,SignalDouble,i,20);
            
      //
      //
      //
      //
      //
                           
      slope[i] = slope[i+1];
      if (cqs[i] > cqs[i+1]) slope[i] =  1;
      if (cqs[i] < cqs[i+1]) slope[i] = -1;
      if (cqs[i]>0)
      if (slope[i]==1)
            cqshuu[i] = cqs[i];
      else  cqshud[i] = cqs[i];
      if (cqs[i]<0)
      if (slope[i]==1)
            cqshdu[i] = cqs[i];
      else  cqshdd[i] = cqs[i];
   }
return(0);
}

//
//
//
//
//

double wrk[][40];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iDSmooth(double price, double length, double phase, bool isDouble, int i, int s=0)
{
   if (isDouble)
         return (iSmooth(iSmooth(price,MathSqrt(length),phase,i,s),MathSqrt(length),phase,i,s+10));
   else  return (iSmooth(price,length,phase,i,s));
}

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}


