//+------------------------------------------------------------------
//|
//+------------------------------------------------------------------
#property copyright "www.forex-tsd.com"
#property link      "www.forex-tsd.com"

#property indicator_separate_window
#property indicator_buffers 5
#property indicator_color1  PaleVioletRed
#property indicator_color2  PaleVioletRed
#property indicator_color3  DeepSkyBlue
#property indicator_color4  DeepSkyBlue
#property indicator_color5  Silver
#property indicator_width1  2
#property indicator_width3  2
#property indicator_width5  2

//
//
//
//
//

extern ENUM_TIMEFRAMES    TimeFrame        = PERIOD_CURRENT;
extern int                DwmaLength       = 12;
extern ENUM_APPLIED_PRICE DwmaPrice        = PRICE_CLOSE;
extern int    JmaLength        = 26;
extern double JmaPhase         =  0;
extern int    JmaPrice         = PRICE_CLOSE;
extern bool   HistogramOnSlope = false;
extern bool   alertsOn         = false;
extern bool   alertsOnSlope    = false;
extern bool   alertsOnCurrent  = true;
extern bool   alertsMessage    = true;
extern bool   alertsSound      = false;
extern bool   alertsEmail      = false;
extern bool   Interpolate      = true;

//
//
//
//
//

double osc[];
double oscUpa[];
double oscUpb[];
double oscDna[];
double oscDnb[];
double trend[];
double slope[];

string indicatorFileName;
bool   returnBars;

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
// 
//
//
//
//

int init()
{
   IndicatorBuffers(7);
   SetIndexBuffer(0,oscDna); SetIndexStyle(0,DRAW_HISTOGRAM);
   SetIndexBuffer(1,oscDnb); SetIndexStyle(1,DRAW_HISTOGRAM);
   SetIndexBuffer(2,oscUpa); SetIndexStyle(2,DRAW_HISTOGRAM);
   SetIndexBuffer(3,oscUpb); SetIndexStyle(3,DRAW_HISTOGRAM);
   SetIndexBuffer(4,osc);
   SetIndexBuffer(5,trend);
   SetIndexBuffer(6,slope);
   
      //
      //
      //
      //
      //
      
         indicatorFileName = WindowExpertName();
         returnBars        = TimeFrame==-99;
         TimeFrame         = MathMax(TimeFrame,_Period);
      
      //
      //
      //
      //
      //
   
      IndicatorShortName(timeFrameToString(TimeFrame)+" dwma - jma oscillator ("+DwmaLength+","+JmaLength+")");
   return(0);
}

//
//
//
//
//

int start()
{
   int counted_bars=IndicatorCounted();
      if(counted_bars<0) return(-1);
      if(counted_bars>0) counted_bars--;
         int limit = MathMin(Bars-counted_bars,Bars-1);
         if (returnBars) { oscDna[0] = limit+1; return(0); }

   //
   //
   //
   //
   //
   
   if (TimeFrame == Period())
   {
      for(int i=limit; i>=0; i--)
      {
         double dwma = iDwma(iMA(NULL,0,1,0,MODE_SMA,DwmaPrice,i),DwmaLength,i);
         double jma  = iSmooth(iMA(NULL,0,1,0,MODE_SMA,JmaPrice,i),JmaLength,JmaPhase,i);
            osc[i]   = jma-dwma;
            oscDna[i] = EMPTY_VALUE;
            oscDnb[i] = EMPTY_VALUE;
            oscUpa[i] = EMPTY_VALUE;
            oscUpb[i] = EMPTY_VALUE;
            trend[i]  = trend[i+1];
            slope[i]  = slope[i+1];
               if (osc[i]>0)        trend[i] =  1;
               if (osc[i]<0)        trend[i] = -1;
               if (osc[i]>osc[i+1]) slope[i] =  1;
               if (osc[i]<osc[i+1]) slope[i] = -1;
               if (HistogramOnSlope)
               {
                  if (trend[i]== 1 && slope[i] == 1) oscUpa[i] = osc[i];
                  if (trend[i]== 1 && slope[i] ==-1) oscUpb[i] = osc[i];
                  if (trend[i]==-1 && slope[i] ==-1) oscDna[i] = osc[i];
                  if (trend[i]==-1 && slope[i] == 1) oscDnb[i] = osc[i];
               }
               else
               {                  
                  if (trend[i]== 1) oscUpa[i] = osc[i];
                  if (trend[i]==-1) oscDna[i] = osc[i];
               }                  
      }
      manageAlerts();
      return(0);
   }      

   //
   //
   //
   //
   //

   limit = MathMax(limit,MathMin(Bars-1,iCustom(NULL,TimeFrame,indicatorFileName,-99,0,0)*TimeFrame/Period()));
   for(i=limit; i>=0; i--)
   {
      int y = iBarShift(NULL,TimeFrame,Time[i]);
         osc[i]    = iCustom(NULL,TimeFrame,indicatorFileName,PERIOD_CURRENT,DwmaLength,DwmaPrice,JmaLength,JmaPhase,JmaPrice,HistogramOnSlope,alertsOn,alertsOnSlope,alertsOnCurrent,alertsMessage,alertsSound,alertsEmail,4,y);
         trend[i]  = iCustom(NULL,TimeFrame,indicatorFileName,PERIOD_CURRENT,DwmaLength,DwmaPrice,JmaLength,JmaPhase,JmaPrice,HistogramOnSlope,alertsOn,alertsOnSlope,alertsOnCurrent,alertsMessage,alertsSound,alertsEmail,5,y);
         slope[i]  = iCustom(NULL,TimeFrame,indicatorFileName,PERIOD_CURRENT,DwmaLength,DwmaPrice,JmaLength,JmaPhase,JmaPrice,HistogramOnSlope,alertsOn,alertsOnSlope,alertsOnCurrent,alertsMessage,alertsSound,alertsEmail,6,y);
         oscDna[i] = EMPTY_VALUE;
         oscDnb[i] = EMPTY_VALUE;
         oscUpa[i] = EMPTY_VALUE;
         oscUpb[i] = EMPTY_VALUE;

         //
         //
         //
         //
         //
      
         if (!Interpolate || y==iBarShift(NULL,TimeFrame,Time[i-1])) continue;

         //
         //
         //
         //
         //

         datetime time = iTime(NULL,TimeFrame,y);
            for(int n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;
            for(int k = 1; k < n; k++)
               osc[i+k]  = osc[i] + (osc[i+n]-osc[i])*k/n;
   }
   for (i=limit;i>=0;i--)
   {
      if (HistogramOnSlope)
      {
         if (trend[i]== 1 && slope[i] == 1) oscUpa[i] = osc[i];
         if (trend[i]== 1 && slope[i] ==-1) oscUpb[i] = osc[i];
         if (trend[i]==-1 && slope[i] ==-1) oscDna[i] = osc[i];
         if (trend[i]==-1 && slope[i] == 1) oscDnb[i] = osc[i];
      }
      else
      {                  
         if (trend[i]== 1) oscUpa[i] = osc[i];
         if (trend[i]==-1) oscDna[i] = osc[i];
      }                  
   }
   
   //
   //
   //
   //
   //
   
   return(0);
}


//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

double workDwma[][2];
double iDwma(double price, double period, int r, int instanceNo=0)
{
   if (ArraySize(workDwma)!= Bars) ArrayResize(workDwma,Bars); r = Bars-r-1; instanceNo*=2;
   
   //
   //
   //
   //
   //

   for (int i=0; i<2; i++)
   {
      workDwma[r][instanceNo+i] = price;
         double sumw = period;
         double sum  = period*price;

         for(int k=1; k<period && (r-k)>=0; k++)
         {
            double weight = period-k;
                  sumw  += weight;
                  sum   += weight*workDwma[r-k][instanceNo+i];  
         }             
         price = sum/sumw;
   }              
   return(price);
}

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

double wrk[][10];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars); s*= 10;
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}

//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------
//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

void manageAlerts()
{
   if (alertsOn)
   {
      if (alertsOnCurrent)
           int whichBar = 0;
      else     whichBar = 1;
      
      //
      //
      //
      //
      //
      
      if (alertsOnSlope)
      {
         if (slope[whichBar] != slope[whichBar+1])
         {
            if (slope[whichBar] == 1) doAlert(whichBar,"slope changed to up");
            if (slope[whichBar] ==-1) doAlert(whichBar,"slope changed to down");
         }         
      }
      else
      {
         if (trend[whichBar] != trend[whichBar+1])
         {
            if (trend[whichBar] == 1) doAlert(whichBar,"crossed zero line up");
            if (trend[whichBar] ==-1) doAlert(whichBar,"crossed zero line down");
         }         
      }         
   }
}   

//
//
//
//
//

void doAlert(int forBar, string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
      if (previousAlert != doWhat || previousTime != Time[forBar]) {
          previousAlert  = doWhat;
          previousTime   = Time[forBar];

          //
          //
          //
          //
          //

          message =  StringConcatenate(Symbol()," ",timeFrameToString(_Period)," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," dpwma & jma oscillator ",doWhat);
             if (alertsMessage) Alert(message);
             if (alertsEmail)   SendMail(StringConcatenate(Symbol(),"dpwma & jma"),message);
             if (alertsSound)   PlaySound("alert2.wav");
      }
}