//+------------------------------------------------------------------+
//|                                                          dmx.mq4 |
//|                                                           mladen |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property indicator_buffers    6
#property indicator_color1     DarkSlateGray
#property indicator_color2     DarkSlateGray
#property indicator_color3     Red
#property indicator_color4     DeepSkyBlue
#property indicator_color5     DimGray
#property indicator_color6     DeepSkyBlue
#property indicator_width6     2
#property indicator_style1     STYLE_DOT
#property indicator_style2     STYLE_DOT
#property indicator_style5     STYLE_DOT


//
//
//
//
//

#import "dynamicZone.dll"
   double dzBuyP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i, double precision );
   double dzSellP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i, double precision );
#import

//
//
//
//
//

extern int    Length                 = 32;
extern int    Phase                  = 0;
extern int    Smooth                 = 5;
extern int    SmoothPhase            = 0;
extern bool   ShowUpDownLimit        = true;
extern int    DzLookBackBars         = 35;
extern double DzStartBuyProbability  = 0.16;
extern double DzStartSellProbability = 0.16;

//
//
//
//
//

double dmx[];
double limU[];
double limD[];
double bli[];
double sli[];
double zli[];



//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   SetIndexBuffer(0,limU); SetIndexLabel(0,NULL);
   SetIndexBuffer(1,limD); SetIndexLabel(1,NULL);
   SetIndexBuffer(2,bli);
   SetIndexBuffer(3,sli);
   SetIndexBuffer(4,zli);
   SetIndexBuffer(5,dmx);  SetIndexLabel(5,"Dmx");
      Smooth =MathMax(Smooth,1);

   //
   //
   //
   //
   //
   
   IndicatorShortName("Dmx ("+Length+","+Smooth+","+DoubleToStr(SmoothPhase,Digits)+")");
   return(0);
}
int deinit() { return(0); }




//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int start()
{
   int counted_bars=IndicatorCounted();
   int i,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
           limit=Bars-counted_bars;

   //
   //
   //
   //
   //
   
   for(i=limit; i>=0; i--)
   {
      double currTR  = iSmooth(MathMax(High[i],Close[i+1])-MathMin(Low[i],Close[i+1]),Length,Phase,i,0);
      double DeltaHi = High[i] - High[i+1];
      double DeltaLo = Low[i+1] - Low[i];
      double plusDM  = 0.00;
      double minusDM = 0.00;

         if ((DeltaHi > DeltaLo) && (DeltaHi > 0)) plusDM  = DeltaHi;
         if ((DeltaLo > DeltaHi) && (DeltaLo > 0)) minusDM = DeltaLo;      
         
      //
      //
      //
      //
      //

         double DIp = 0.00;
         double DIm = 0.00;

            if (currTR > 0.00)
            {
               DIp = 100.0*iSmooth(plusDM ,Length,Phase,i,10)/currTR;
               DIm = 100.0*iSmooth(minusDM,Length,Phase,i,20)/currTR;
            }
            if ((DIp+DIm) != 0)
                  dmx[i] = 100.00*iSmooth((DIp-DIm)/(DIp+DIm),Smooth,SmoothPhase,i,30);
            else  dmx[i] = 100.00*iSmooth(0                  ,Smooth,SmoothPhase,i,30);

            bli[i] = dzBuyP (dmx, DzStartBuyProbability,  DzLookBackBars, Bars, i,0.001);
            sli[i] = dzSellP(dmx, DzStartSellProbability, DzLookBackBars, Bars, i,0.001);
            zli[i] = dzSellP(dmx, 0.5,                    DzLookBackBars, Bars, i,0.001);
         
      //
      //
      //
      //
      //
               
      if (ShowUpDownLimit)
      {
         limD[i] = -100;
         limU[i] =  100;
      }         
   }   

   //
   //
   //
   //
   //
   
   return(0);      
}

//+------------------------------------------------------------------
//|                                                                 
//+------------------------------------------------------------------
//
//
//
//
//

double wrk[][40];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s)
{
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[0][k+s]= price; for(; k<10; k++) wrk[0][k+s]= 0; return(price); }

   //
   //
   //
   //
   //
   
      double len1 = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1 = MathMax(len1-2.0,0.5);
      double del1 = price - wrk[r-1][bsmax+s];
      double del2 = price - wrk[r-1][bsmin+s];
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum] =	wrk[r-1][vsum+s] + 0.1*(wrk[r][volty+s]-wrk[r-10][volty+s]);
   
         //
         //
         //
         //
         //
      
         double avgLen = MathMin(MathMax(4.0*length,30),150);
            if (r<avgLen)
            {
               double avg = wrk[r][vsum+s];  for (k=1; k<avgLen && (r-k)>=0 ; k++) avg += wrk[r-k][vsum+s];
                                                                                   avg /= k;
            }
            else avg = (wrk[r-1][avolty+s]*avgLen-wrk[r-toInt(avgLen)][vsum+s]+wrk[r][vsum+s])/avgLen;
            
         //
         //
         //
         //
         //
                                                           
         wrk[r][avolty+s] = avg;                                           
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));		
	
         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;

   //
   //
   //
   //
   //

      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}
int toInt(double value) { return(value); }

