//+------------------------------------------------------------------------+
//|                                                       dynamic zone 3m3 |
//| as described by Walter Bressert in his article                         |
//| Trading With Time Fractals to Reduce Risk and Improve Profit Potential |
//+------------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property indicator_buffers 4
#property indicator_color1  DeepSkyBlue
#property indicator_color2  LimeGreen
#property indicator_color3  Red
#property indicator_color4  DimGray
#property indicator_width1  2
#property indicator_style4  STYLE_DOT  

//
//
//
//
//

#import "dynamicZone.dll"
   double dzBuyP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i, double precission );
   double dzSellP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i, double precission );
#import

//
//
//
//
//

extern int    RsiLength              = 3;
extern int    RsiPrice               = PRICE_CLOSE;
extern int    SmoothPeriod           = 3;
extern int    DetrendPeriod          = 5;
extern int    DzLookBackBars         = 70;
extern double DzStartBuyProbability  = 0.10;
extern double DzStartSellProbability = 0.10;

//
//
//
//
//

double det[];
double rsi[];
double rsiSmoothed[];
double bli[];
double sli[];
double zli[];

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   IndicatorBuffers(6);
   SetIndexBuffer(0,det);
   SetIndexBuffer(1,bli);
   SetIndexBuffer(2,sli);
   SetIndexBuffer(3,zli);
   SetIndexBuffer(4,rsi);
   SetIndexBuffer(5,rsiSmoothed);

   //
   //
   //
   //
   //
   
   string PriceType;
      switch(RsiPrice)
      {
         case PRICE_CLOSE:    PriceType = "Close";    break;  // 0
         case PRICE_OPEN:     PriceType = "Open";     break;  // 1
         case PRICE_HIGH:     PriceType = "High";     break;  // 2
         case PRICE_LOW:      PriceType = "Low";      break;  // 3
         case PRICE_MEDIAN:   PriceType = "Median";   break;  // 4
         case PRICE_TYPICAL:  PriceType = "Typical";  break;  // 5
         case PRICE_WEIGHTED: PriceType = "Weighted"; break;  // 6
      }      

   //
   //
   //
   //
   //

   RsiLength = MathMax(RsiLength ,1);
   IndicatorShortName ("Dynamic zone 3M3 ("+RsiLength+","+PriceType+","+DzLookBackBars+","+DoubleToStr(DzStartBuyProbability,3)+","+DoubleToStr(DzStartSellProbability,3)+")");
   return(0);
}
int deinit()
{
   return(0);
}

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int start()
{
   int counted_bars=IndicatorCounted();
   int i,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);

   //
   //
   //
   //
   //
   //

   for(i=limit; i >= 0; i--)
   {
      rsi[i] = iRSI(NULL,0,RsiLength,RsiPrice,i);    
      double rsiSmooth = rsi[i];
         for (int k=1; k<SmoothPeriod; k++) rsiSmooth += rsi[i+k];
                                            rsiSmooth /= SmoothPeriod;
      rsiSmoothed[i] = rsiSmooth;
      
      double rsiDet = rsiSmoothed[i];
         for (k=1; k<DetrendPeriod; k++) rsiDet += rsiSmoothed[i+k];
                                         rsiDet /= DetrendPeriod;
      det[i] = rsiSmooth-rsiDet;
      bli[i] = dzBuyP (det,DzStartBuyProbability,  DzLookBackBars, Bars, i, 0.0001);
      sli[i] = dzSellP(det,DzStartSellProbability, DzLookBackBars, Bars, i, 0.0001);
      zli[i] = dzBuyP (det,0.5,                    DzLookBackBars, Bars, i, 0.0001);
   }
   return(0);
}