//+------------------------------------------------------------------+
//|                       double dynamic zone williams percent range |
//|                                                           mladen |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property indicator_buffers 6
#property indicator_color1  DeepSkyBlue
#property indicator_color2  LimeGreen
#property indicator_color3  Red
#property indicator_color4  LimeGreen
#property indicator_color5  Red
#property indicator_color6  Gold
#property indicator_width1  3
#property indicator_width4  2
#property indicator_width5  2
#property indicator_style2  STYLE_DOT
#property indicator_style3  STYLE_DOT
#property indicator_style6  STYLE_DASH


//
//
//
//
//

#import "dynamicZone.dll"
   double dzBuy(double& sourceArray[],double initValue, int lookBack, int bars, int i);
   double dzSell(double& sourceArray[],double initValue, int lookBack, int bars, int i);
#import

//
//
//
//
//

extern string TimeFrame               = "current time frame";
extern int    HLR_Range               = 50;
extern int    Length                  = 25;
extern double Speed                   = 8;
extern bool   Adaptive                = true;
extern int    DzLookBackBars          = 70;
extern double DzStartBuyProbability1  = 0.20;
extern double DzStartSellProbability1 = 0.20;
extern double DzStartBuyProbability2  = 0.06;
extern double DzStartSellProbability2 = 0.06;
extern bool   Interpolate             = true;

//
//
//
//
//

double HLR_Buffer[];
double bli1[];
double sli1[];
double bli2[];
double sli2[];
double slic[];
double stored[][21];

int    timeFrame;
string IndicatorFileName;
bool   Calculatinghilo;
bool   ReturningBars;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   IndicatorBuffers(6);
   SetIndexBuffer(0,HLR_Buffer);
   SetIndexBuffer(1,bli1);
   SetIndexBuffer(2,sli1);
   SetIndexBuffer(3,bli2);
   SetIndexBuffer(4,sli2);
   SetIndexBuffer(5,slic);
   
   Length = MathMax(Length,   1);
   Speed  = MathMax(Speed ,-1.5);

   //
   //
   //
   //
   //
   
   //
      //
      //
      //
      //
         
         IndicatorFileName = WindowExpertName();
         Calculatinghilo   = (TimeFrame=="calculatehilo"); if (ReturningBars)  return(0);
         ReturningBars     = (TimeFrame=="returnBars");    if (ReturningBars)  return(0);
         timeFrame         = stringToTimeFrame(TimeFrame);
      
      //
      //
      //
      //
      //
         
   string shortName = "Dynamic zone Range_osc on oma "+timeFrameToString(TimeFrame)+" ("+HLR_Range+")";
   IndicatorShortName(shortName);
   return(0);
}
int deinit()
{
   return(0);
}

//+------------------------------------------------------------------+
//|                                                                  |
//+-------------------------------------------------------------------


int start()
{
   int counted_bars=IndicatorCounted();
   int i,r,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);
         if (ReturningBars)  { HLR_Buffer[0] = limit+1; return(0); }
         if (ArrayRange(stored,0) != Bars) ArrayResize(stored,Bars);
         
         
   if (Calculatinghilo || timeFrame==Period())
   {  

   for(i=limit, r=Bars-limit-1; i>=0; i--,r++)
   {
   
      double hhv  = iAverage(High[iHighest(NULL, 0, MODE_HIGH, HLR_Range, i)],Length,Speed,Adaptive,r,0);
      double llv  = iAverage(Low[iLowest(NULL, 0,   MODE_LOW,  HLR_Range, i)],Length,Speed,Adaptive,r,7);
      double m_pr = iAverage((High[i] + Low[i]) / 2.0,                        Length,Speed,Adaptive,r,14);
      HLR_Buffer[i] = 100.0 * (m_pr - llv) / (hhv - llv); 
      bli1[i] = dzBuy (HLR_Buffer, DzStartBuyProbability1,  DzLookBackBars, Bars, i);
      sli1[i] = dzSell(HLR_Buffer, DzStartSellProbability1, DzLookBackBars, Bars, i);
      bli2[i] = dzBuy (HLR_Buffer, DzStartBuyProbability2,  DzLookBackBars, Bars, i);
      sli2[i] = dzSell(HLR_Buffer, DzStartSellProbability2, DzLookBackBars, Bars, i);
      slic[i] = dzSell(HLR_Buffer, 0.5                    , DzLookBackBars, Bars, i);
   }
   return(0);
}

limit = MathMax(limit,MathMin(Bars-1,iCustom(NULL,timeFrame,IndicatorFileName,"returnBars",0,0)*timeFrame/Period()));
   for(i=limit; i>=0; i--)
   {
      int y = iBarShift(NULL,timeFrame,Time[i]);
      HLR_Buffer[i] = iCustom(NULL,timeFrame,IndicatorFileName,"calculatehilo",HLR_Range,Length,Speed,Adaptive,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,0,y);
      bli1[i]       = iCustom(NULL,timeFrame,IndicatorFileName,"calculatehilo",HLR_Range,Length,Speed,Adaptive,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,1,y);
      sli1[i]       = iCustom(NULL,timeFrame,IndicatorFileName,"calculatehilo",HLR_Range,Length,Speed,Adaptive,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,2,y);
      bli2[i]       = iCustom(NULL,timeFrame,IndicatorFileName,"calculatehilo",HLR_Range,Length,Speed,Adaptive,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,3,y);
      sli2[i]       = iCustom(NULL,timeFrame,IndicatorFileName,"calculatehilo",HLR_Range,Length,Speed,Adaptive,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,4,y);
      slic[i]       = iCustom(NULL,timeFrame,IndicatorFileName,"calculatehilo",HLR_Range,Length,Speed,Adaptive,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,5,y);
      
      if (timeFrame <= Period() || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;
         if (!Interpolate) continue;

         //
         //
         //
         //
         //

         datetime time = iTime(NULL,timeFrame,y);
            for(int n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
            double factor = 1.0 / n;
            for(int k = 1; k < n; k++)
            {
               HLR_Buffer[i+k]= k*factor*HLR_Buffer[i+n]+ (1.0-k*factor)*HLR_Buffer[i];
               bli1[i+k]      = k*factor*bli1[i+n]      + (1.0-k*factor)*bli1[i];
               sli1[i+k]      = k*factor*sli1[i+n]      + (1.0-k*factor)*sli1[i];
               bli2[i+k]      = k*factor*bli2[i+n]      + (1.0-k*factor)*bli2[i];
               sli2[i+k]      = k*factor*sli2[i+n]      + (1.0-k*factor)*sli2[i];
               slic[i+k]      = k*factor*slic[i+n]      + (1.0-k*factor)*slic[i];
            }
   }      
   //
   //
   //
   //
   //
   
   return(0);
}



#define E1  0
#define E2  1
#define E3  2
#define E4  3
#define E5  4
#define E6  5
#define res 6

//
//
//
//
//

double iAverage(double price, double averagePeriod, double const1, bool adaptive, int r, int ashift=0)
{
   double e1=stored[r-1][E1+ashift];  double e2=stored[r-1][E2+ashift];
   double e3=stored[r-1][E3+ashift];  double e4=stored[r-1][E4+ashift];
   double e5=stored[r-1][E5+ashift];  double e6=stored[r-1][E6+ashift];

   //
   //
   //
   //
   //

      if (adaptive && (averagePeriod > 1))
      {
         double minPeriod = averagePeriod/2.0;
         double maxPeriod = minPeriod*5.0;
         int    endPeriod = MathCeil(maxPeriod);
         double signal    = MathAbs((price-stored[r-endPeriod][res]));
         double noise     = 0.00000000001;

            for(int k=1; k<endPeriod; k++) noise=noise+MathAbs(price-stored[r-k][res]);

         averagePeriod = ((signal/noise)*(maxPeriod-minPeriod))+minPeriod;
      }
      
      //
      //
      //
      //
      //
      
      double alpha = ((2.0+const1)/(1.0+const1+averagePeriod));

      e1 = e1 + alpha*(price-e1); e2 = e2 + alpha*(e1-e2); double v1 = 1.5 * e1 - 0.5 * e2;
      e3 = e3 + alpha*(v1   -e3); e4 = e4 + alpha*(e3-e4); double v2 = 1.5 * e3 - 0.5 * e4;
      e5 = e5 + alpha*(v2   -e5); e6 = e6 + alpha*(e5-e6); double v3 = 1.5 * e5 - 0.5 * e6;

   //
   //
   //
   //
   //

   stored[r][E1+ashift]  = e1;  stored[r][E2+ashift] = e2;
   stored[r][E3+ashift]  = e3;  stored[r][E4+ashift] = e4;
   stored[r][E5+ashift]  = e5;  stored[r][E6+ashift] = e6;
   stored[r][res+ashift] = price;
   return(v3);
}

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = StringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//


string StringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int char1 = StringGetChar(s, length);
         if((char1 > 96 && char1 < 123) || (char1 > 223 && char1 < 256))
                     s = StringSetChar(s, length, char1 - 32);
         else if(char1 > -33 && char1 < 0)
                     s = StringSetChar(s, length, char1 + 224);
   }
   return(s);
}

