#property copyright "www.forex-tsd.com"
#property link      "www.forex-tsd.com"

#property indicator_separate_window
#property indicator_buffers  6
#property indicator_color1   Goldenrod
#property indicator_color2   LimeGreen
#property indicator_color3   LimeGreen
#property indicator_color4   Red
#property indicator_color5   Red
#property indicator_color6   DimGray
#property indicator_style3   STYLE_DOT
#property indicator_style4   STYLE_DOT
#property indicator_style6   STYLE_DOT
#property indicator_width1   2

//
//
//
//
//

#import "dynamicZone.dll"
   double dzBuyP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i, double precision);
   double dzSellP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i, double precision);
#import




extern string TimeFrame               = "Current time frame";
extern double SmoothPhase             = 0;
extern bool   SmoothDouble            = true;
extern int    DzLookBackBars          = 70;
extern double DzStartBuyProbability1  = 0.1;
extern double DzStartBuyProbability2  = 0.25;
extern double DzStartSellProbability1 = 0.1;
extern double DzStartSellProbability2 = 0.25;
extern bool   Interpolate             = true;

extern bool   alertsOn                = true;
extern bool   alertsOnCurrent         = false;
extern bool   alertsMessage           = true;
extern bool   alertsSound             = false;
extern bool   alertsEmail             = false;
extern bool   ShowArrows              = false;
extern string arrowsIdentifier        = "Complex on jurik arrows";
extern color  arrowsUpColor           = LimeGreen;
extern color  arrowsDnColor           = Crimson;










double pair[];
double bl1Buffer[];
double bl2Buffer[];
double sl1Buffer[];
double sl2Buffer[];
double zliBuffer[];
double trend[];


// for monthly
int mn_per = 12;
int mn_fast = 3;

// for weekly
int w_per = 9;
int w_fast = 3;

// for daily
int d_per = 5;
int d_fast = 3;

// for H4
int h4_per = 12;
int h4_fast = 2;

// for H1
int h1_per = 24;
int h1_fast = 8;

// for M30
int m30_per = 16;
int m30_fast = 2;

// for M15
int m15_per = 16;
int m15_fast = 4;

// for M5
int m5_per = 12;
int m5_fast = 3;

// for M1
int m1_per = 30;
int m1_fast = 10;

string indicatorFileName;
bool   calculateValue;
bool   returnBars;
int    timeFrame;


int init()
  {
   IndicatorBuffers(7);
   SetIndexBuffer(0,pair);
   SetIndexBuffer(1,bl1Buffer);
   SetIndexBuffer(2,bl2Buffer);
   SetIndexBuffer(3,sl2Buffer);
   SetIndexBuffer(4,sl1Buffer);
   SetIndexBuffer(5,zliBuffer);
   SetIndexBuffer(6,trend);
   
   
   
   indicatorFileName = WindowExpertName();
   calculateValue    = (TimeFrame=="calculateValue"); if (calculateValue) return(0);
   returnBars        = (TimeFrame=="returnBars");     if (returnBars)     return(0);
   timeFrame         = stringToTimeFrame(TimeFrame);
   
   
   IndicatorShortName(Symbol() +  timeFrameToString(timeFrame));
  
  
   return(0);
  }

int deinit(){  if (!calculateValue && ShowArrows) deleteArrows();  return(0); }



int start()
  {
   
   int per1, per2;
   int counted_bars=IndicatorCounted();
   int i,n,k,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);
         if (returnBars) { pair[0] = limit+1; return(0); }
         if (calculateValue || timeFrame == Period())
         {
         
       switch(Period())
       {
       case 1:     per1 = m1_per;  per2 = m1_fast;  break;
       case 5:     per1 = m5_per;  per2 = m5_fast;  break;
       case 15:    per1 = m15_per; per2 = m15_fast; break;
       case 30:    per1 = m30_per; per2 = m30_fast; break;
       case 60:    per1 = h1_per;  per2 = h1_fast;  break;
       case 240:   per1 = h4_per;  per2 = h4_fast;  break;
       case 1440:  per1 = d_per;   per2 = d_fast;   break;
       case 10080: per1 = w_per;   per2 = w_fast;   break;
       case 43200: per1 = mn_per;  per2 = mn_fast;  break;
       }
       for(i=limit; i>=0; i--)
       {
      double OPEN   = iDSmooth(iMA(NULL,0,1,0,MODE_SMA,PRICE_OPEN,i), per2,SmoothPhase,SmoothDouble,i,  0)-
                      iDSmooth(iMA(NULL,0,1,0,MODE_SMA,PRICE_OPEN,i), per1,SmoothPhase,SmoothDouble,i, 20);
      double HIGH   = iDSmooth(iMA(NULL,0,1,0,MODE_SMA,PRICE_HIGH,i), per2,SmoothPhase,SmoothDouble,i, 40)-
                      iDSmooth(iMA(NULL,0,1,0,MODE_SMA,PRICE_HIGH,i), per1,SmoothPhase,SmoothDouble,i, 60);
      double LOW    = iDSmooth(iMA(NULL,0,1,0,MODE_SMA,PRICE_LOW,i),  per2,SmoothPhase,SmoothDouble,i, 80)-
                      iDSmooth(iMA(NULL,0,1,0,MODE_SMA,PRICE_LOW,i),  per1,SmoothPhase,SmoothDouble,i,100);
      double CLOSE  = iDSmooth(iMA(NULL,0,1,0,MODE_SMA,PRICE_CLOSE,i),per2,SmoothPhase,SmoothDouble,i,120)-
                      iDSmooth(iMA(NULL,0,1,0,MODE_SMA,PRICE_CLOSE,i),per1,SmoothPhase,SmoothDouble,i,140);
             pair[i]= (OPEN + HIGH + LOW + CLOSE) / 4;
             
      if (DzStartBuyProbability1  > 0) bl1Buffer[i] = dzBuyP (pair, DzStartBuyProbability1,  DzLookBackBars, Bars, i, 0.0001);
      if (DzStartBuyProbability2  > 0) bl2Buffer[i] = dzBuyP (pair, DzStartBuyProbability2,  DzLookBackBars, Bars, i, 0.0001);
      if (DzStartSellProbability1 > 0) sl1Buffer[i] = dzSellP(pair, DzStartSellProbability1, DzLookBackBars, Bars, i, 0.0001);
      if (DzStartSellProbability2 > 0) sl2Buffer[i] = dzSellP(pair, DzStartSellProbability2, DzLookBackBars, Bars, i, 0.0001);
                                       zliBuffer[i] = dzSellP(pair, 0.5                    , DzLookBackBars, Bars, i, 0.0001);
                                           trend[i] = trend[i+1];
                     
           if (pair[i] > zliBuffer[i] && pair[i+1] <= zliBuffer[i+1]) trend[i] =  1;
           if (pair[i] < zliBuffer[i] && pair[i+1] >= zliBuffer[i+1]) trend[i] = -1;
            
           if (!calculateValue) manageArrow(i);
      }
      manageAlerts();
      return (0);
   }        
   
   
  limit = MathMax(limit,MathMin(Bars,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
    for (i=limit;i>=0; i--)
    {
    int y        = iBarShift(NULL,timeFrame,Time[i]);
    pair[i]      = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",SmoothPhase,SmoothDouble,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,0,y);
    bl1Buffer[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",SmoothPhase,SmoothDouble,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,1,y);
    bl2Buffer[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",SmoothPhase,SmoothDouble,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,2,y);
    sl2Buffer[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",SmoothPhase,SmoothDouble,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,3,y);
    sl1Buffer[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",SmoothPhase,SmoothDouble,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,4,y);
    zliBuffer[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",SmoothPhase,SmoothDouble,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,5,y); 
    trend[i]     = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",SmoothPhase,SmoothDouble,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,6,y);
    
    manageArrow(i);
    
    switch(Period())
       {
       case 1:     per1 = m1_per;  per2 = m1_fast;  break;
       case 5:     per1 = m5_per;  per2 = m5_fast;  break;
       case 15:    per1 = m15_per; per2 = m15_fast; break;
       case 30:    per1 = m30_per; per2 = m30_fast; break;
       case 60:    per1 = h1_per;  per2 = h1_fast;  break;
       case 240:   per1 = h4_per;  per2 = h4_fast;  break;
       case 1440:  per1 = d_per;   per2 = d_fast;   break;
       case 10080: per1 = w_per;   per2 = w_fast;   break;
       case 43200: per1 = mn_per;  per2 = mn_fast;  break;
       }
       
        if (!Interpolate || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;

         //
         //
         //
         //
         //

         datetime time = iTime(NULL,timeFrame,y);
            for(n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
            for(k = 1; k < n; k++)
            {
               pair[i+k]      = pair[i]      + (pair[i+n]     -pair[i])     *k/n;
               bl1Buffer[i+k] = bl1Buffer[i] + (bl1Buffer[i+n]-bl1Buffer[i])*k/n;
               bl2Buffer[i+k] = bl2Buffer[i] + (bl2Buffer[i+n]-bl2Buffer[i])*k/n;
               sl2Buffer[i+k] = sl2Buffer[i] + (sl2Buffer[i+n]-sl2Buffer[i])*k/n;
               sl1Buffer[i+k] = sl1Buffer[i] + (sl1Buffer[i+n]-sl1Buffer[i])*k/n;
               zliBuffer[i+k] = zliBuffer[i] + (zliBuffer[i+n]-zliBuffer[i])*k/n;
            }
   }

   //
   //
   //
   //
   //
   manageAlerts();
   return(0);
}

void manageAlerts()
{
   if (!calculateValue && alertsOn)
   {
      if (alertsOnCurrent)
           int whichBar = 0;
      else     whichBar = 1; whichBar = iBarShift(NULL,0,iTime(NULL,timeFrame,whichBar));
      if (trend[whichBar] != trend[whichBar+1])
      {
         if (trend[whichBar] ==  1) doAlert(whichBar,"up");
         if (trend[whichBar] == -1) doAlert(whichBar,"down");
      }
   }
}

//
//
//
//
//

void doAlert(int forBar, string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
   if (previousAlert != doWhat || previousTime != Time[forBar]) {
       previousAlert  = doWhat;
       previousTime   = Time[forBar];

       //
       //
       //
       //
       //

       message =  StringConcatenate(Symbol()," ",timeFrameToString(timeFrame)," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," Complex on jurik trend changed to ",doWhat);
          if (alertsMessage) Alert(message);
          if (alertsEmail)   SendMail(StringConcatenate(Symbol()," Complex on jurik "),message);
          if (alertsSound)   PlaySound("alert2.wav");
   }
}


//
//
//
//
//

void manageArrow(int i)
{
   if (ShowArrows)
   {
      deleteArrow(Time[i]);
      if (trend[i]!=trend[i+1])
      {
         if (trend[i] == 1) drawArrow(i,arrowsUpColor,225,false);
         if (trend[i] ==-1) drawArrow(i,arrowsDnColor,226,true);
      }
   }
}               

//
//
//
//
//

void drawArrow(int i,color theColor,int theCode,bool up)
{
   string name = arrowsIdentifier+":"+Time[i];
   double gap  = 3.0*iATR(NULL,0,20,i)/4.0;   
   
      //
      //
      //
      //
      //
      
      ObjectCreate(name,OBJ_ARROW,0,Time[i],0);
         ObjectSet(name,OBJPROP_ARROWCODE,theCode);
         ObjectSet(name,OBJPROP_COLOR,theColor);
         if (up)
               ObjectSet(name,OBJPROP_PRICE1,High[i]+gap);
         else  ObjectSet(name,OBJPROP_PRICE1,Low[i] -gap);
}

//
//
//
//
//

void deleteArrows()
{
   string lookFor       = arrowsIdentifier+":";
   int    lookForLength = StringLen(lookFor);
   for (int i=ObjectsTotal()-1; i>=0; i--)
   {
      string objectName = ObjectName(i);
         if (StringSubstr(objectName,0,lookForLength) == lookFor) ObjectDelete(objectName);
   }
}
void deleteArrow(datetime time)
{
   string lookFor = arrowsIdentifier+":"+time; ObjectDelete(lookFor);
}
//
string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = stringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string stringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int char1 = StringGetChar(s, length);
         if((char1 > 96 && char1 < 123) || (char1 > 223 && char1 < 256))
                     s = StringSetChar(s, length, char1 - 32);
         else if(char1 > -33 && char1 < 0)
                     s = StringSetChar(s, length, char1 + 224);
   }
   return(s);
}


double wrk[][160];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iDSmooth(double price, double length, double phase, bool isDouble, int i, int s=0)
{
   if (isDouble)
         return (iSmooth(iSmooth(price,MathSqrt(length),phase,i,s),MathSqrt(length),phase,i,s+10));
   else  return (iSmooth(price,length,phase,i,s));
}

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}


