//+------------------------------------------------------------------+
//|                                    Spearman Rank Correlation.mq4 |
//+------------------------------------------------------------------+
#property copyright "www.forex-tsd.com"
#property link      "www.forex-tsd.com"

#property indicator_separate_window
#property indicator_buffers  8
#property indicator_color1   Goldenrod
#property indicator_color2   DodgerBlue
#property indicator_color3   DodgerBlue
#property indicator_color4   Crimson
#property indicator_color5   Crimson
#property indicator_color6   LimeGreen
#property indicator_color7   Red
#property indicator_color8   Magenta
#property indicator_style8   STYLE_DASH
#property indicator_width1   4
#property indicator_width2   5
#property indicator_width3   5
#property indicator_width4   5
#property indicator_width5   5
#property indicator_width6   1
#property indicator_width7   1
#property indicator_minimum -1.05
#property indicator_maximum  1.05

//
//
//
//
//

#import "dynamicZone.dll"
   double dzBuyP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i, double precision);
   double dzSellP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i, double precision);
#import "spearman.dll"
   double rankSpearman(double& sourceArray[],bool isSeries, int rank, int bars, int i);
#import

//
//
//
//
//

extern string TimeFrame              = "Current time frame";
extern int    Rank                   = 14;
extern int    Length                 = 5;
extern double Phase                  = 0;
extern int    Price                  = PRICE_CLOSE;
extern int    DzLookBackBars         = 70;
extern double DzStartBuyProbability  = 0.05;
extern double DzStartSellProbability = 0.05;
extern bool   Interpolate            = true;
extern bool   alertsOn               = true;
extern bool   alertsOnCurrent        = true;
extern bool   alertsMessage          = true;
extern bool   alertsSound            = false;
extern bool   alertsEmail            = false;

//
//
//
//
//

double rank[];
double rankUa[];
double rankUb[];
double rankDa[];
double rankDb[];
double bli[];
double sli[];
double zli[];
double prices[];
double trend[];

//
//
//
//
//

string indicatorFileName;
bool   returnBars;
bool   calculateValue;
int    timeFrame;


//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   IndicatorBuffers(8);
   SetIndexBuffer(0, rank);
   SetIndexBuffer(1, rankUa);
   SetIndexBuffer(2, rankUb);
   SetIndexBuffer(3, rankDa);
   SetIndexBuffer(4, rankDb);
   SetIndexBuffer(5, bli);
   SetIndexBuffer(6, sli);
   SetIndexBuffer(7, zli);
   
      //
      //
      //
      //
      //
      
         Rank = MathMax(Rank,10);
         indicatorFileName = WindowExpertName();
         calculateValue    = TimeFrame=="calculateValue"; if (calculateValue) { return(0); }
         returnBars        = TimeFrame=="returnBars";     if (returnBars)     { return(0); }
         timeFrame         = stringToTimeFrame(TimeFrame);

         
      //
      //
      //
      //
      //
          
   IndicatorShortName(timeFrameToString(timeFrame)+" Spearman on  ds jurik (" + Rank + ")");
   return(0);
}
int deinit()
{
   return(0);
}


//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int start()
{
   double coef         = MathPow(Rank,3) - Rank;
   double calcLength   = MathSqrt(Length);
   int    counted_bars = IndicatorCounted();
   int    i,k,r,n,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);
         if (returnBars) { rank[0] = MathMin(limit+1,Bars-1); return(0); }

   //
   //
   //
   //
   //

   if (ArraySize(prices)!= Bars) { ArrayResize(prices,Bars); ArrayResize(trend,Bars); }
   if (calculateValue || timeFrame == Period())
   {
      if (!calculateValue && trend[Bars-limit-1]== 1) CleanPoint(limit,rankUa,rankUb);
      if (!calculateValue && trend[Bars-limit-1]==-1) CleanPoint(limit,rankDa,rankDb);
      for(i = limit, r=Bars-i-1; i >= 0; i--,r++)
      {
         prices[r] = iDSmooth(iMA(NULL,0,1,0,MODE_SMA,Price,i),Length,Phase,i,0);
         rankUa[i] = EMPTY_VALUE;
         rankUb[i] = EMPTY_VALUE;
         rankDa[i] = EMPTY_VALUE;
         rankDb[i] = EMPTY_VALUE;
         rank[i]   = rankSpearman(prices,false,Rank,Bars,i);
         bli[i]    = dzBuyP (rank, DzStartBuyProbability,  DzLookBackBars, Bars, i, 0.0001);
         sli[i]    = dzSellP(rank, DzStartSellProbability, DzLookBackBars, Bars, i, 0.0001);
         zli[i]    = dzSellP(rank, 0.5,                    DzLookBackBars, Bars, i, 0.0001);
         trend[r]  = trend[r-1];
         trend[r]  = 0;
         
            //
            //
            //
            //
            //
            
            if (rank[i]>rank[i+1])                                        trend[r]= 1;
            if (rank[i]<rank[i+1])                                        trend[r]=-1;
            if (rank[i]<bli[i] && rank[i]>sli[i])                         trend[r]= 0;
            if (!calculateValue && trend[r] ==  1) PlotPoint(i,rankUa,rankUb,rank);
            if (!calculateValue && trend[r] == -1) PlotPoint(i,rankDa,rankDb,rank);
            if (calculateValue) rankUa[i] = trend[r];
      }      
      manageAlerts();
      return(0);
   }      
   
   //
   //
   //
   //
   //
   
   limit = MathMax(limit,MathMin(Bars,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
   for (i=limit, r=Bars-i-1;i>=0;i--,r++)
   {
      int y = iBarShift(NULL,timeFrame,Time[i]);
         rank[i]   = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Rank,Length,Phase,Price,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,0,y);
         trend[r]  = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Rank,Length,Phase,Price,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,1,y);
         bli[i]    = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Rank,Length,Phase,Price,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,5,y);
         sli[i]    = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Rank,Length,Phase,Price,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,6,y);
         zli[i]    = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Rank,Length,Phase,Price,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,7,y);
         rankUa[i] = EMPTY_VALUE;
         rankUb[i] = EMPTY_VALUE;
         rankDa[i] = EMPTY_VALUE;
         rankDb[i] = EMPTY_VALUE;

         //
         //
         //
         //
         //
      
         if (!Interpolate || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;

         //
         //
         //
         //
         //

         datetime time = iTime(NULL,timeFrame,y);
            for(n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
            for(k = 1; k < n; k++)
            {
               rank[i+k] = rank[i] + (rank[i+n]-rank[i])*k/n;
               bli[i+k]  = bli[i]  + (bli[i+n] -bli[i] )*k/n;
               sli[i+k]  = sli[i]  + (sli[i+n] -sli[i] )*k/n;
               zli[i+k]  = zli[i]  + (zli[i+n] -zli[i] )*k/n;
            }
   }
   for (i=limit,r=Bars-i-1;i>=0;i--,r++)
   {
      if (trend[r]== 1) PlotPoint(i,rankUa,rankUb,rank);
      if (trend[r]==-1) PlotPoint(i,rankDa,rankDb,rank);
   }
   
   //
   //
   //
   //
   //
   
   manageAlerts();
   return(0);
}


//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------
//
//
//
//
//

void manageAlerts()
{
   if (!calculateValue && alertsOn)
   {
      if (alertsOnCurrent)
           int whichBar = 0;
      else     whichBar = 1; whichBar = iBarShift(NULL,0,iTime(NULL,timeFrame,whichBar));
      if (trend[Bars-whichBar-1] != trend[Bars-whichBar-2])
      {
         if (trend[Bars-whichBar-1] ==  1) doAlert(whichBar,DoubleToStr(sli[whichBar]  ,4)+" broken up");
         if (trend[Bars-whichBar-1] == -1) doAlert(whichBar,DoubleToStr(bli[whichBar]  ,4)+" broken down");
         if (trend[Bars-whichBar-2] == -1) doAlert(whichBar,DoubleToStr(bli[whichBar+1],4)+" broken up");
         if (trend[Bars-whichBar-2] ==  1) doAlert(whichBar,DoubleToStr(sli[whichBar+1],4)+" broken down");
      }
   }
}

//
//
//
//
//

void doAlert(int forBar, string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
   if (previousAlert != doWhat || previousTime != Time[forBar]) {
       previousAlert  = doWhat;
       previousTime   = Time[forBar];

       //
       //
       //
       //
       //

       message =  StringConcatenate(Symbol()," ",timeFrameToString(timeFrame)," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," spearman level ",doWhat);
          if (alertsMessage) Alert(message);
          if (alertsEmail)   SendMail(StringConcatenate(Symbol(),"Spearman rank"),message);
          if (alertsSound)   PlaySound("alert2.wav");
   }
}

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

void CleanPoint(int i,double& first[],double& second[])
{
   if ((second[i]  != EMPTY_VALUE) && (second[i+1] != EMPTY_VALUE))
        second[i+1] = EMPTY_VALUE;
   else
      if ((first[i] != EMPTY_VALUE) && (first[i+1] != EMPTY_VALUE) && (first[i+2] == EMPTY_VALUE))
          first[i+1] = EMPTY_VALUE;
}

//
//
//
//
//

void PlotPoint(int i,double& first[],double& second[],double& from[])
{
   if (first[i+1] == EMPTY_VALUE)
      {
         if (first[i+2] == EMPTY_VALUE) {
                first[i]   = from[i];
                first[i+1] = from[i+1];
                second[i]  = EMPTY_VALUE;
            }
         else {
                second[i]   =  from[i];
                second[i+1] =  from[i+1];
                first[i]    = EMPTY_VALUE;
            }
      }
   else
      {
         first[i]  = from[i];
         second[i] = EMPTY_VALUE;
      }
}

//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------
//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = stringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string stringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int char1 = StringGetChar(s, length);
         if((char1 > 96 && char1 < 123) || (char1 > 223 && char1 < 256))
                     s = StringSetChar(s, length, char1 - 32);
         else if(char1 > -33 && char1 < 0)
                     s = StringSetChar(s, length, char1 + 224);
   }
   return(s);
}


double wrk[][20];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iDSmooth(double price, double length, double phase, int i, int s=0)
{
   return (iSmooth(iSmooth(price,length,phase,i,s),length,phase,i,s+10));
}

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}