//+------------------------------------------------------------------+
//|                                    kase permision stochastic.mq4 |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property indicator_buffers  7
#property indicator_color1  Magenta
#property indicator_color2  DimGray
#property indicator_color3  LimeGreen
#property indicator_color4  Red
#property indicator_color5  LimeGreen
#property indicator_color6  Red
#property indicator_color7  Gold
#property indicator_width1  3
#property indicator_width5  2
#property indicator_width6  2
#property indicator_style2  STYLE_DASHDOT
#property indicator_style3  STYLE_DOT
#property indicator_style4  STYLE_DOT
#property indicator_style7  STYLE_DASH




#import "dynamicZone.dll"
   double dzBuy(double& sourceArray[],double initValue, int lookBack, int bars, int i );
   double dzSell(double& sourceArray[],double initValue, int lookBack, int bars, int i );
#import

//
//
//
//
//
extern string TimeFrame               = "current time frame";
extern int    pstLength               =   9;
extern int    pstX                    =   5;
extern int    pstSmooth               =   3;
extern int    smoothPeriod            =  10;
extern int    smoothPhase             = 100;
extern int    DzLookBackBars          = 70;
extern double DzStartBuyProbability1  = 0.20;
extern double DzStartSellProbability1 = 0.20;
extern double DzStartBuyProbability2  = 0.06;
extern double DzStartSellProbability2 = 0.06;
extern bool   Interpolate             = true;


//
//
//
//
//

double pstBuffer[];
double pssBuffer[];
double bli1[];
double sli1[];
double bli2[];
double sli2[];
double slic[];

int    timeFrame;
string IndicatorFileName;
bool   Calculatingkase;
bool   ReturningBars;

double wrkBuffer[][5];

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   SetIndexBuffer(0,pstBuffer);
   SetIndexBuffer(1,pssBuffer);
   SetIndexBuffer(2,bli1);
   SetIndexBuffer(3,sli1);
   SetIndexBuffer(4,bli2);
   SetIndexBuffer(5,sli2);
   SetIndexBuffer(6,slic);
   
      pstSmooth    = MathMax(pstSmooth,1);
      smoothPeriod = MathMax(smoothPeriod,1);
      
      IndicatorFileName = WindowExpertName();
      Calculatingkase   = (TimeFrame=="calculatekase"); if (ReturningBars)  return(0);
      ReturningBars     = (TimeFrame=="returnBars");    if (ReturningBars)  return(0);
      timeFrame         = stringToTimeFrame(TimeFrame);
      
      //
      //
      //
      //
      //
         
   string shortName = " Dynamic Zone Kase permission stochastic smoothed "+timeFrameToString(TimeFrame)+" ("+pstLength+","+pstX+")";
   IndicatorShortName(shortName);
   return(0);
}

int deinit() { return(0); }




//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

#define TripleK   0
#define TripleDF  1
#define TripleDFs 2
#define TripleDS  3
#define TripleDSs 4

//
//
//
//
//

int start()
{
   double alpha = 2.0/(1.0+pstSmooth);
   int lookBackPeriod = pstLength*pstX;
   int counted_bars   = IndicatorCounted();
   int i,r,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);
         if (ArrayRange(wrkBuffer,0) != Bars) ArrayResize(wrkBuffer,Bars);
         if (ReturningBars)  { pstBuffer[0] = limit+1; return(0); }
         
         
         
   
   if (Calculatingkase || timeFrame==Period())
   {  

   for(i=limit,r=Bars-i-1; i>=0; i--,r++)
   {
      double min = Low [iLowest (NULL,0,MODE_LOW ,lookBackPeriod,i)];
      double max = High[iHighest(NULL,0,MODE_HIGH,lookBackPeriod,i)]-min;
      if (max>0)
            wrkBuffer[r][TripleK] = 100.0*(Close[i]-min)/max;
      else  wrkBuffer[r][TripleK] =   0.0;
      if (i==(Bars-1))
      {
            wrkBuffer[r][TripleDF] = wrkBuffer[r][TripleK];
            wrkBuffer[r][TripleDS] = wrkBuffer[r][TripleK];
            continue;
      }
      wrkBuffer[r][TripleDF] =  wrkBuffer[r-pstX][TripleDF]+alpha*(wrkBuffer[r][TripleK]-wrkBuffer[r-pstX][TripleDF]);
      wrkBuffer[r][TripleDS] = (wrkBuffer[r-pstX][TripleDS]*2.0+wrkBuffer[r][TripleDF])/3.0;
      
      //
      //
      //
      //
      //
      
      wrkBuffer[r][TripleDSs] = iSma(TripleDS ,3,r);
      pssBuffer[i]            = iSmooth(wrkBuffer[r][TripleDSs],smoothPeriod,smoothPhase,i, 0);
      wrkBuffer[r][TripleDFs] = iSma(TripleDF ,3,r);
      pstBuffer[i]            = iSmooth(wrkBuffer[r][TripleDFs],smoothPeriod,smoothPhase,i,10);
      bli1[i] = dzBuy (pstBuffer, DzStartBuyProbability1,  DzLookBackBars, Bars, i);
      sli1[i] = dzSell(pstBuffer, DzStartSellProbability1, DzLookBackBars, Bars, i);
      bli2[i] = dzBuy (pstBuffer, DzStartBuyProbability2,  DzLookBackBars, Bars, i);
      sli2[i] = dzSell(pstBuffer, DzStartSellProbability2, DzLookBackBars, Bars, i);
      slic[i] = dzSell(pstBuffer, 0.5                    , DzLookBackBars, Bars, i);
   }
   return(0);
}
   limit = MathMax(limit,MathMin(Bars-1,iCustom(NULL,timeFrame,IndicatorFileName,"returnBars",0,0)*timeFrame/Period()));
   for(i=limit; i>=0; i--)
   {
      int y = iBarShift(NULL,timeFrame,Time[i]);
      pstBuffer[i]  = iCustom(NULL,timeFrame,IndicatorFileName,"calculatekase",pstLength,pstX,pstSmooth,smoothPeriod,smoothPhase,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,0,y);
      pssBuffer[i]  = iCustom(NULL,timeFrame,IndicatorFileName,"calculatekase",pstLength,pstX,pstSmooth,smoothPeriod,smoothPhase,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,1,y);
      bli1[i]       = iCustom(NULL,timeFrame,IndicatorFileName,"calculatekase",pstLength,pstX,pstSmooth,smoothPeriod,smoothPhase,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,2,y);
      sli1[i]       = iCustom(NULL,timeFrame,IndicatorFileName,"calculatekase",pstLength,pstX,pstSmooth,smoothPeriod,smoothPhase,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,3,y);
      bli2[i]       = iCustom(NULL,timeFrame,IndicatorFileName,"calculatekase",pstLength,pstX,pstSmooth,smoothPeriod,smoothPhase,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,4,y);
      sli2[i]       = iCustom(NULL,timeFrame,IndicatorFileName,"calculatekase",pstLength,pstX,pstSmooth,smoothPeriod,smoothPhase,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,5,y);
      slic[i]       = iCustom(NULL,timeFrame,IndicatorFileName,"calculatekase",pstLength,pstX,pstSmooth,smoothPeriod,smoothPhase,DzLookBackBars,DzStartBuyProbability1,DzStartSellProbability1,DzStartBuyProbability2,DzStartSellProbability2,6,y);
      
      if (timeFrame <= Period() || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;
         if (!Interpolate) continue;

         //
         //
         //
         //
         //

         datetime time = iTime(NULL,timeFrame,y);
            for(int n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
            double factor = 1.0 / n;
            for(int k = 1; k < n; k++)
            {
               pstBuffer[i+k]= k*factor*pstBuffer[i+n]+ (1.0-k*factor)*pstBuffer[i];
               pssBuffer[i+k]= k*factor*pssBuffer[i+n]+ (1.0-k*factor)*pssBuffer[i];
               bli1[i+k]     = k*factor*bli1[i+n]     + (1.0-k*factor)*bli1[i];
               sli1[i+k]     = k*factor*sli1[i+n]     + (1.0-k*factor)*sli1[i];
               bli2[i+k]     = k*factor*bli2[i+n]     + (1.0-k*factor)*bli2[i];
               sli2[i+k]     = k*factor*sli2[i+n]     + (1.0-k*factor)*sli2[i];
               slic[i+k]     = k*factor*slic[i+n]     + (1.0-k*factor)*slic[i];
            }
   }      
   //
   //
   //
   //
   //
   
   return(0);
}


string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = StringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string StringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int char1 = StringGetChar(s, length);
         if((char1 > 96 && char1 < 123) || (char1 > 223 && char1 < 256))
                     s = StringSetChar(s, length, char1 - 32);
         else if(char1 > -33 && char1 < 0)
                     s = StringSetChar(s, length, char1 + 224);
   }
   return(s);
}




//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

double iSma(int forDim, int period, int pos)
{
   double sum = wrkBuffer[pos][forDim];
      for(int i=1; i<period; i++) sum += wrkBuffer[pos-i][forDim];
   return(sum/period);
}


//+------------------------------------------------------------------
//|                                                                 
//+------------------------------------------------------------------
//
//
//
//
//

double wrk[][20];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[0][k+s]= price; for(; k<10; k++) wrk[0][k+s]= 0; return(price); }

   //
   //
   //
   //
   //
   
      double len1 = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1 = MathMax(len1-2.0,0.5);
      double del1 = price - wrk[r-1][bsmax+s];
      double del2 = price - wrk[r-1][bsmin+s];
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + 0.1*(wrk[r][volty+s]-wrk[r-10][volty+s]);
   
         //
         //
         //
         //
         //
      
         double avgLen = MathMin(MathMax(4.0*length,30),150);
            if (r<avgLen)
            {
               double avg = wrk[r][vsum+s];  for (k=1; k<avgLen && (r-k)>=0 ; k++) avg += wrk[r-k][vsum+s];
                                                                                   avg /= k;
            }
            else avg = (wrk[r-1][avolty+s]*avgLen-wrk[r-toInt(avgLen)][vsum+s]+wrk[r][vsum+s])/avgLen;
            
         //
         //
         //
         //
         //
                                                           
         wrk[r][avolty+s] = avg;                                           
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));		
	
         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;

   //
   //
   //
   //
   //

      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}
int toInt(double value) { return(value); }