//+------------------------------------------------------------------+
//|                                       Price and Volume Trend.mq4 |
//|                      Copyright © 2007, MetaQuotes Software Corp. |
//|                                       http://www.metaquotes.net/ |
//+------------------------------------------------------------------+
#property copyright "www.forex-tsd.com"
#property link      "www.forex-tsd.com"

#property indicator_separate_window
#property indicator_buffers 8
#property indicator_color1  clrLimeGreen
#property indicator_color2  clrSilver
#property indicator_color3  clrPaleVioletRed
#property indicator_color4  clrSilver
#property indicator_color5  clrLimeGreen
#property indicator_color6  clrLimeGreen
#property indicator_color7  clrPaleVioletRed
#property indicator_color8  clrPaleVioletRed
#property indicator_width4  2
#property indicator_width5  2
#property indicator_width6  2
#property indicator_width7  2
#property indicator_width8  2
#property indicator_style1  STYLE_DOT
#property indicator_style2  STYLE_DOT
#property indicator_style3  STYLE_DOT
#property strict

#import "dynamicZone.dll"
   double dzBuyP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i,double precision);
   double dzSellP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i,double precision);
#import

//
//
//
//
//

enum enPrices
{
   pr_close,      // Close
   pr_open,       // Open
   pr_high,       // High
   pr_low,        // Low
   pr_median,     // Median
   pr_typical,    // Typical
   pr_weighted,   // Weighted
   pr_average,    // Average (high+low+open+close)/4
   pr_medianb,    // Average median body (open+close)/2
   pr_tbiased,    // Trend biased price
   pr_haclose,    // Heiken ashi close
   pr_haopen ,    // Heiken ashi open
   pr_hahigh,     // Heiken ashi high
   pr_halow,      // Heiken ashi low
   pr_hamedian,   // Heiken ashi median
   pr_hatypical,  // Heiken ashi typical
   pr_haweighted, // Heiken ashi weighted
   pr_haaverage,  // Heiken ashi average
   pr_hamedianb,  // Heiken ashi median body
   pr_hatbiased   // Heiken ashi trend biased price
};
enum enColorOn
{
   clr_onOut,  // Change color on outer levels cross
   clr_onZer   // Change color on zero cross
};

extern enPrices  ExtPVTAppliedPrice = pr_weighted; // Price to use
extern double    LevelUp            = 90;          // Level up (%)
extern double    LevelDown          = 10;          // Level down (%)
extern int       LookBackBars       = 75;          // Look back bars no
extern enColorOn ColorOn            = clr_onOut;   // Change color on :

double pvt[],pvtda[],pvtdb[],pvtua[],pvtub[],dzup[],dzmi[],dzdn[],prices[],state[];

//------------------------------------------------------------------
//
//------------------------------------------------------------------

int init()
{
   IndicatorDigits(0);     
   IndicatorBuffers(10);
      SetIndexBuffer(0, dzup);
      SetIndexBuffer(1, dzmi);
      SetIndexBuffer(2, dzdn);
      SetIndexBuffer(3, pvt);
      SetIndexBuffer(4, pvtua);
      SetIndexBuffer(5, pvtub);
      SetIndexBuffer(6, pvtda);
      SetIndexBuffer(7, pvtdb);
      SetIndexBuffer(8, prices);
      SetIndexBuffer(9, state);
   IndicatorShortName("Price and Volume Trend");
   return(0);
}
int start()
{
   int i,counted_bars = IndicatorCounted(); 
      if (counted_bars < 0) return(-1); 
      if (counted_bars > 0) counted_bars--;  
         int limit=MathMin(Bars-counted_bars,Bars-1);

   //
   //
   //
   //
   //
   
   if (state[limit]== 1) CleanPoint(limit,pvtua,pvtub);
   if (state[limit]==-1) CleanPoint(limit,pvtda,pvtdb);
   for (i= limit; i >= 0; i--) 
   {
      prices[i] = getPrice(ExtPVTAppliedPrice,Open,Close,High,Low,i);
      if(i == Bars - 1) 
         { pvt[i] = (double)Volume[i]; continue; }
      
      //
      //
      //
      //
      //
      
      state[i] = 0;
      pvt[i]  = pvt[i+1] + Volume[i]*(prices[i]-prices[i+1])/prices[i+1];  
      dzup[i] = dzBuyP (pvt,  LevelUp  /100,LookBackBars,Bars,i,0.1);
      dzdn[i] = dzSellP(pvt,1-LevelDown/100,LookBackBars,Bars,i,0.1);
      dzmi[i] = dzBuyP (pvt,            0.5,LookBackBars,Bars,i,0.1);
      if (ColorOn==clr_onOut)
      {
         if (pvt[i]<dzdn[i]) state[i] = -1;
         if (pvt[i]>dzup[i]) state[i] =  1;
      }
      else
      {
         if (pvt[i]<dzmi[i]) state[i] = -1;
         if (pvt[i]>dzmi[i]) state[i] =  1;
      }         
      if (state[i] == 1) PlotPoint(i,pvtua,pvtub,pvt);
      if (state[i] ==-1) PlotPoint(i,pvtda,pvtdb,pvt);
   }
   return(0);
}

//-------------------------------------------------------------------
//                                                                  
//-------------------------------------------------------------------
//
//
//
//
//

double workHa[][4];
double getPrice(int price, const double& open[], const double& close[], const double& high[], const double& low[], int i, int instanceNo=0)
{
  if (price>=pr_haclose && price<=pr_hatbiased)
   {
      if (ArrayRange(workHa,0)!= Bars) ArrayResize(workHa,Bars); instanceNo*=4;
         int r = Bars-i-1;
         
         //
         //
         //
         //
         //
         
         double haOpen;
         if (r>0)
                haOpen  = (workHa[r-1][instanceNo+2] + workHa[r-1][instanceNo+3])/2.0;
         else   haOpen  = (open[i]+close[i])/2;
         double haClose = (open[i] + high[i] + low[i] + close[i]) / 4.0;
         double haHigh  = MathMax(high[i], MathMax(haOpen,haClose));
         double haLow   = MathMin(low[i] , MathMin(haOpen,haClose));

         if(haOpen  <haClose) { workHa[r][instanceNo+0] = haLow;  workHa[r][instanceNo+1] = haHigh; } 
         else                 { workHa[r][instanceNo+0] = haHigh; workHa[r][instanceNo+1] = haLow;  } 
                                workHa[r][instanceNo+2] = haOpen;
                                workHa[r][instanceNo+3] = haClose;
         //
         //
         //
         //
         //
         
         switch (price)
         {
            case pr_haclose:     return(haClose);
            case pr_haopen:      return(haOpen);
            case pr_hahigh:      return(haHigh);
            case pr_halow:       return(haLow);
            case pr_hamedian:    return((haHigh+haLow)/2.0);
            case pr_hamedianb:   return((haOpen+haClose)/2.0);
            case pr_hatypical:   return((haHigh+haLow+haClose)/3.0);
            case pr_haweighted:  return((haHigh+haLow+haClose+haClose)/4.0);
            case pr_haaverage:   return((haHigh+haLow+haClose+haOpen)/4.0);
            case pr_hatbiased:
               if (haClose>haOpen)
                     return((haHigh+haClose)/2.0);
               else  return((haLow+haClose)/2.0);        
         }
   }
   
   //
   //
   //
   //
   //
   
   switch (price)
   {
      case pr_close:     return(close[i]);
      case pr_open:      return(open[i]);
      case pr_high:      return(high[i]);
      case pr_low:       return(low[i]);
      case pr_median:    return((high[i]+low[i])/2.0);
      case pr_medianb:   return((open[i]+close[i])/2.0);
      case pr_typical:   return((high[i]+low[i]+close[i])/3.0);
      case pr_weighted:  return((high[i]+low[i]+close[i]+close[i])/4.0);
      case pr_average:   return((high[i]+low[i]+close[i]+open[i])/4.0);
      case pr_tbiased:   
               if (close[i]>open[i])
                     return((high[i]+close[i])/2.0);
               else  return((low[i]+close[i])/2.0);        
   }
   return(0);
}

//-------------------------------------------------------------------
//                                                                  
//-------------------------------------------------------------------
//
//
//
//
//

void CleanPoint(int i,double& first[],double& second[])
{
   if (i>=Bars-3) return;
   if ((second[i]  != EMPTY_VALUE) && (second[i+1] != EMPTY_VALUE))
        second[i+1] = EMPTY_VALUE;
   else
      if ((first[i] != EMPTY_VALUE) && (first[i+1] != EMPTY_VALUE) && (first[i+2] == EMPTY_VALUE))
          first[i+1] = EMPTY_VALUE;
}

void PlotPoint(int i,double& first[],double& second[],double& from[])
{
   if (i>=Bars-2) return;
   if (first[i+1] == EMPTY_VALUE)
      if (first[i+2] == EMPTY_VALUE) 
            { first[i]  = from[i];  first[i+1]  = from[i+1]; second[i] = EMPTY_VALUE; }
      else  { second[i] =  from[i]; second[i+1] = from[i+1]; first[i]  = EMPTY_VALUE; }
   else     { first[i]  = from[i];                           second[i] = EMPTY_VALUE; }
}