//+----------------------------------------------------------------------------+
//|                                                               iProfit.mq4  |
//|                                                    Ким Игорь В. aka KimIV  |
//|                                                       http://www.kimiv.ru  |
//+----------------------------------------------------------------------------+
#property indicator_chart_window

//------- Внешние параметры индикатора ----------------------------------------+
extern int   Magic     = 0;            // Magic
extern int   Corner    = 0;            // Corner
extern int   FontSize  = 11;           // Fonts Size
extern int   eiOffsetY = 89;           // Смещение текста по вертикали
extern int   eiStepY   = 15;           // Шаг смещения текста по вертикали
extern int   eiX1Row   = 8;            // Координата X первой колонки
extern int   eiX2Row   = 180;          // Координата X второй колонки
extern int   eiX3Row   = 240;          // Координата X третей колонки
extern color ecText    = Gold;         // Цвет текста
extern color ecProfit  = Green;        // Цвет прибыли
extern color ecLoss    = Crimson;      // Цвет убытка

//+----------------------------------------------------------------------------+
//|  Custom indicator initialization function                                  |
//+----------------------------------------------------------------------------+
void init()
{
  DeleteObjects();
  Comment("");
}

//+----------------------------------------------------------------------------+
//|  Custom indicator deinitialization function                                |
//+----------------------------------------------------------------------------+
void deinit()
{
  DeleteObjects();
  Comment("");
}

//+----------------------------------------------------------------------------+
//|  Custom indicator iteration function                                       |
//+----------------------------------------------------------------------------+
void start() {
  datetime d0, d1, d2, d3, d4, d5, d6, d7, d8;

  d0=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE));
  while (TimeDayOfWeek(d0)<1 || TimeDayOfWeek(d0)>5) d0-=24*60*60;
  d1=d0-24*60*60;
  while (TimeDayOfWeek(d1)<1 || TimeDayOfWeek(d1)>5) d1-=24*60*60;
  d2=d1-24*60*60;
  while (TimeDayOfWeek(d2)<1 || TimeDayOfWeek(d2)>5) d2-=24*60*60;
  d3=d2-24*60*60;
  while (TimeDayOfWeek(d3)<1 || TimeDayOfWeek(d3)>5) d3-=24*60*60;
  d4=d3-24*60*60;
  while (TimeDayOfWeek(d4)<1 || TimeDayOfWeek(d4)>5) d4-=24*60*60;
  d5=DateOfMonday();
  d6=StrToTime(Year()+"."+Month()+".01");
  d7=DateBeginQuarter();
  d8=StrToTime(Year()+".01.01");

  double tu=GetProfitOpenPosInPoint();
  double u0=GetProfitFromDateInPoint("", -1, -1, d0);
  double u1=GetProfitFromDateInPoint("", -1, -1, d1)-u0;
  double u5=GetProfitFromDateInPoint("", -1, -1, d5);
  double u6=GetProfitFromDateInPoint("", -1, -1, d6);
  double u8=GetProfitFromDateInPoint("", -1, -1, d8);

  double tb=AccountBalance(), tp=AccountProfit();
  double p0=GetProfitFromDateInCurrency("", -1, -1, d0);
  double p1=GetProfitFromDateInCurrency("", -1, -1, d1)-p0;
  double p5=GetProfitFromDateInCurrency("", -1, -1, d5);
  double p6=GetProfitFromDateInCurrency("", -1, -1, d6);
  double p8=GetProfitFromDateInCurrency("", -1, -1, d8);

  // Изменение баланса
  double h0=GetChangeBalance("", -1, -1, d0);
  double h5=GetChangeBalance("", -1, -1, d5);
  double h6=GetChangeBalance("", -1, -1, d6);
  double h7=GetChangeBalance("", -1, -1, d7);
  double h8=GetChangeBalance("", -1, -1, d8);

  string st;

  SetLabel("iProfit05", "Profit:", ecText, eiX1Row, eiOffsetY);
  SetLabel("iProfit06", "Points", ecText, eiX2Row-95, eiOffsetY);
  SetLabel("iProfit07", "Money", ecText, eiX3Row-85, eiOffsetY);

  SetLabel("iProfit11", "Current", ecText, eiX1Row, eiOffsetY+1*eiStepY);
  SetLabel("iProfit21", "Today", ecText, eiX1Row, eiOffsetY+2*eiStepY);
  SetLabel("iProfit71", "Week", ecText, eiX1Row, eiOffsetY+3*eiStepY);
  SetLabel("iProfit81", "Month", ecText, eiX1Row, eiOffsetY+4*eiStepY);
  SetLabel("iProfit01", "Year", ecText, eiX1Row, eiOffsetY+5*eiStepY);

  SetLabel("iProfit12", DoubleToStr(tu, 0), ColorOnSign(tp), eiX2Row-95, eiOffsetY+1*eiStepY);
  SetLabel("iProfit22", DoubleToStr(u0, 0), ColorOnSign(u0), eiX2Row-95, eiOffsetY+2*eiStepY);
  SetLabel("iProfit72", DoubleToStr(u5, 0), ColorOnSign(u5), eiX2Row-95, eiOffsetY+3*eiStepY);
  SetLabel("iProfit82", DoubleToStr(u6, 0), ColorOnSign(u6), eiX2Row-95, eiOffsetY+4*eiStepY);
  SetLabel("iProfit02", DoubleToStr(u8, 0), ColorOnSign(u8), eiX2Row-95, eiOffsetY+5*eiStepY);

  SetLabel("iProfit13", DoubleToStr(tp, 2), ColorOnSign(tp), eiX3Row-85, eiOffsetY+1*eiStepY);
  SetLabel("iProfit23", DoubleToStr(p0, 2), ColorOnSign(p0), eiX3Row-85, eiOffsetY+2*eiStepY);
  SetLabel("iProfit73", DoubleToStr(p5, 2), ColorOnSign(p5), eiX3Row-85, eiOffsetY+3*eiStepY);
  SetLabel("iProfit83", DoubleToStr(p6, 2), ColorOnSign(p6), eiX3Row-85, eiOffsetY+4*eiStepY);
  SetLabel("iProfit03", DoubleToStr(p8, 2), ColorOnSign(p8), eiX3Row-85, eiOffsetY+5*eiStepY);
}

//+----------------------------------------------------------------------------+
//|  Возвращает цвет по знаку числа                                            |
//+----------------------------------------------------------------------------+
color ColorOnSign(double nu) {
  color lcColor=ecText;

  if (nu>0) lcColor=ecProfit;
  if (nu<0) lcColor=ecLoss;

  return(lcColor);
}

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 12.05.2008                                                     |
//|  Описание : Возвращает дату начала квартала                                |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|                                    (-2 - позапрошлый)                      |
//|                                    (-1 - прошлый)                          |
//|    no - номер квартала             ( 0 - текущий)                          |
//|                                    ( 1 - следующий)                        |
//|                                    ( 2 - последующий)                      |
//+----------------------------------------------------------------------------+
datetime DateBeginQuarter(int nk=0) {
  int ye=Year()-MathFloor(nk/4);
  nk=MathMod(nk, 4);
  int mo=Month()-MathMod(Month()+2, 3)+3*nk;
  if (mo<1) {
    mo+=12;
    ye--;
  }
  if (mo>12) {
    mo-=12;
    ye++;
  }

  return(StrToTime(ye+"."+mo+".01"));
}

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 12.05.2008                                                     |
//|  Описание : Возвращает дату понедельника                                   |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|                                    (-2 - позатой недели)                   |
//|                                    (-1 - прошлой недели)                   |
//|    no - номер понедельника         ( 0 - текущей недели)                   |
//|                                    ( 1 - следующий, ближайший будущий)     |
//|                                    ( 2 - последующий)                      |
//+----------------------------------------------------------------------------+
datetime DateOfMonday(int no=0) {
  datetime dt=StrToTime(TimeToStr(TimeCurrent(), TIME_DATE));

  while (TimeDayOfWeek(dt)!=1) dt-=24*60*60;
  dt+=no*7*24*60*60;

  return(dt);
}

//+----------------------------------------------------------------------------+
//|  Удаление объектов.                                                        |
//+----------------------------------------------------------------------------+
void DeleteObjects() {
  string st="iProfit";
  int    i, j;

  for (i=0; i<10; i++) {
    for (j=1; j<8; j++) ObjectDelete(st+i+j);
  }
}

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 30.04.2010                                                     |
//|  Описание : Возвращает суммарный профит в валюте депозита                  |
//|             закрытых с определённой даты позиций                           |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента             (""   - любой символ,         |
//|                                               NULL - текущий символ)       |
//|    op - операция                             (-1   - любая позиция)        |
//|    mn - MagicNumber                          (-1   - любой магик)          |
//|    dt - Дата и время в секундах с 1970 года  ( 0   - с начала истории)     |
//+----------------------------------------------------------------------------+
double GetChangeBalance(string sy="", int op=-1, int mn=-1, datetime dt=0)
{
  double p=0;
  int    i, k=OrdersHistoryTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_HISTORY)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (OrderType()==6) {
          if (Magic<0 || OrderMagicNumber()==Magic) {
            if (dt<OrderCloseTime()) {
              if (OrderProfit()<0) p+=OrderProfit();
            }
          }
        }
      }
    }
  }
  return(p);
}

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает суммарный профит в валюте депозита                  |
//|             закрытых с определённой даты позиций                           |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента             (""   - любой символ,         |
//|                                               NULL - текущий символ)       |
//|    op - операция                             (-1   - любая позиция)        |
//|    mn - MagicNumber                          (-1   - любой магик)          |
//|    dt - Дата и время в секундах с 1970 года  ( 0   - с начала истории)     |
//+----------------------------------------------------------------------------+
double GetProfitFromDateInCurrency(string sy="", int op=-1, int mn=-1, datetime dt=0)
{
  double p=0;
  int    i, k=OrdersHistoryTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_HISTORY)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (Magic<0 || OrderMagicNumber()==Magic) {
            if (dt<OrderCloseTime()) {
              p+=OrderProfit()+OrderCommission()+OrderSwap();
            }
          }
        }
      }
    }
  }
  return(p);
}

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 04.02.2009                                                     |
//|  Описание : Возвращает суммарный профит в пунктах                          |
//|             закрытых с определённой даты позиций                           |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента             (""   - любой символ,         |
//|                                               NULL - текущий символ)       |
//|    op - операция                             (-1   - любая позиция)        |
//|    mn - MagicNumber                          (-1   - любой магик)          |
//|    dt - Дата и время в секундах с 1970 года  ( 0   - с начала истории)     |
//+----------------------------------------------------------------------------+
double GetProfitFromDateInPoint(string sy="", int op=-1, int mn=-1, datetime dt=0)
{
  double p=0, po;
  int    i, k=OrdersHistoryTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_HISTORY)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (Magic<0 || OrderMagicNumber()==Magic) {
            if (dt<OrderCloseTime()) {
              po=MarketInfo(OrderSymbol(), MODE_POINT);
              if (po==0) if (StringFind(sy, "JPY")<0) po=0.0001; else po=0.01;
              if (OrderType()==OP_BUY) {
                p+=(OrderClosePrice()-OrderOpenPrice())/po;
              }
              if (OrderType()==OP_SELL) {
                p+=(OrderOpenPrice()-OrderClosePrice())/po;
              }
            }
          }
        }
      }
    }
  }
  return(p);
}

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 01.08.2008                                                     |
//|  Описание : Возвращает суммарный профит открытых позиций в пунктах         |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
int GetProfitOpenPosInPoint(string sy="", int op=-1) {
  double p;
  int    i, k=OrdersTotal(), pr=0;

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (Magic<0 || OrderMagicNumber()==Magic) {
          p=MarketInfo(OrderSymbol(), MODE_POINT);
          if (p==0) if (StringFind(OrderSymbol(), "JPY")<0) p=0.0001; else p=0.01;
          if (OrderType()==OP_BUY) {
            pr+=(MarketInfo(OrderSymbol(), MODE_BID)-OrderOpenPrice())/p;
          }
          if (OrderType()==OP_SELL) {
            pr+=(OrderOpenPrice()-MarketInfo(OrderSymbol(), MODE_ASK))/p;
          }
        }
      }
    }
  }
  return(pr);
}

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 12.10.2007                                                     |
//|  Описание : Установка текстовой метки                                      |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    nm - наименование объекта                                               |
//|    tx - текст                                                              |
//|    cl - цвет метки                                                         |
//|    xd - координата X в пикселах                                            |
//|    yd - координата Y в пикселах                                            |
//|    fs - размер шрифта              (8 - по умолчанию)                      |
//+----------------------------------------------------------------------------+
void SetLabel(string nm, string tx, color cl, int xd, int yd) {
  if (ObjectFind(nm)<0) ObjectCreate(nm, OBJ_LABEL, 0, 0, 0);
  ObjectSetText(nm, tx, FontSize);
  ObjectSet(nm, OBJPROP_COLOR    , cl);
  ObjectSet(nm, OBJPROP_XDISTANCE, xd);
  ObjectSet(nm, OBJPROP_YDISTANCE, yd);
  ObjectSet(nm, OBJPROP_CORNER   , Corner);
  ObjectSet(nm, OBJPROP_FONTSIZE , FontSize);
}
//+----------------------------------------------------------------------------+

