//+------------------------------------------------------------------+
//|                                        dynamic zone smoothed rsi |
//|                                                           mladen |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property indicator_buffers 4
#property indicator_color1  LimeGreen
#property indicator_color2  LimeGreen
#property indicator_color3  Orange
#property indicator_color4  Orange
#property indicator_width1  2
#property indicator_width3  2
#property indicator_maximum 1
#property indicator_minimum 0

//
//
//
//
//

#import "dynamicZone.dll"
   double dzBuy(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i );
   double dzSell(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i );
#import

//
//
//
//
//

enum enPrices
{
   pr_close,      // Close
   pr_open,       // Open
   pr_high,       // High
   pr_low,        // Low
   pr_median,     // Median
   pr_typical,    // Typical
   pr_weighted,   // Weighted
   pr_average,    // Average (high+low+open+close)/4
   pr_medianb,    // Average median body (open+close)/2
   pr_tbiased,    // Trend biased price
   pr_haclose,    // Heiken ashi close
   pr_haopen ,    // Heiken ashi open
   pr_hahigh,     // Heiken ashi high
   pr_halow,      // Heiken ashi low
   pr_hamedian,   // Heiken ashi median
   pr_hatypical,  // Heiken ashi typical
   pr_haweighted, // Heiken ashi weighted
   pr_haaverage,  // Heiken ashi average
   pr_hamedianb,  // Heiken ashi median body
   pr_hatbiased   // Heiken ashi trend biased price
};

extern int      CciLength              = 10;
extern enPrices CciPrice               = pr_typical;
extern int      CciSmooth              = 3;
extern int      DzLookBackBars         = 70;
extern double   DzStartBuyProbability  = 0.16;
extern double   DzStartSellProbability = 0.16;

//
//
//
//
//

double cci[];
double ccs[];
double ccw[];
double histuu[];
double histum[];
double histdd[];
double histdm[];
double state[];
double prices[];

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   IndicatorBuffers(9);
   SetIndexBuffer(0,histuu); SetIndexStyle(0,DRAW_HISTOGRAM);
   SetIndexBuffer(1,histum); SetIndexStyle(1,DRAW_HISTOGRAM);
   SetIndexBuffer(2,histdd); SetIndexStyle(2,DRAW_HISTOGRAM);
   SetIndexBuffer(3,histdm); SetIndexStyle(3,DRAW_HISTOGRAM);
   SetIndexBuffer(4,ccs);
   SetIndexBuffer(5,cci);
   SetIndexBuffer(6,ccw);
   SetIndexBuffer(7,state);
   SetIndexBuffer(8,prices);

   //
   //
   //
   //
   //
   
      CciLength = MathMax(CciLength ,1);
   IndicatorShortName ("Dynamic zone CCI histo ("+CciLength+","+DzLookBackBars+","+DoubleToStr(DzStartBuyProbability,3)+","+DoubleToStr(DzStartSellProbability,3)+")");
   return(0);
}
int deinit()
{
   return(0);
}

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

double alpha;
int start()
{
   int k,counted_bars=IndicatorCounted();
      if(counted_bars<0) return(-1);
      if(counted_bars>0) counted_bars--;
         int limit = MathMin(Bars-counted_bars,Bars-1);
         alpha = 2.0 /(1.0+MathSqrt(CciSmooth));

   //
   //
   //
   //
   //
   //

   for(int i=limit; i >= 0; i--)
   {
      prices[i]  = getPrice(CciPrice,Open,Close,High,Low,i);
      double avg = 0; for(k=0; k<CciLength && (i+k)<Bars; k++) avg +=         prices[i+k];      avg /= CciLength;
      double dev = 0; for(k=0; k<CciLength && (i+k)<Bars; k++) dev += MathAbs(prices[i+k]-avg); dev /= CciLength;
         if (dev!=0)
               cci[i] = (prices[i]-avg)/(0.015*dev);
         else  cci[i] = 0;
         if (i==Bars-1)
         {
            ccw[i] = cci[i];
            ccs[i] = cci[i];
            continue;
         }
      
      if (CciSmooth>1)
      {
            ccw[i] = ccw[i+1]+alpha*(cci[i]-ccw[i+1]);
            ccs[i] = ccs[i+1]+alpha*(ccw[i]-ccs[i+1]);
      }
      else  ccs[i] = cci[i];         
      double bli = dzBuy (ccs, DzStartBuyProbability,  DzLookBackBars, Bars, i);
      double sli = dzSell(ccs, DzStartSellProbability, DzLookBackBars, Bars, i);
      double cen = dzSell(ccs, 0.5,                    DzLookBackBars, Bars, i);
      histuu[i] = EMPTY_VALUE;
      histum[i] = EMPTY_VALUE;
      histdd[i] = EMPTY_VALUE;
      histdm[i] = EMPTY_VALUE;
      state[i]  = state[i+1];
         if (ccs[i]>cen) state[i] =  1;
         if (ccs[i]>sli) state[i] =  2;
         if (ccs[i]<cen) state[i] = -1;
         if (ccs[i]<bli) state[i] = -2;
         if (state[i] == 2) histuu[i] = 1;
         if (state[i] == 1) histum[i] = 1;
         if (state[i] ==-1) histdm[i] = 1;
         if (state[i] ==-2) histdd[i] = 1;
   }
   return(0);
}

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//
//

double workHa[][4];
double getPrice(int price, const double& open[], const double& close[], const double& high[], const double& low[], int i, int instanceNo=0)
{
  if (price>=pr_haclose && price<=pr_hatbiased)
   {
      if (ArrayRange(workHa,0)!= Bars) ArrayResize(workHa,Bars);
         int r = Bars-i-1;
         
         //
         //
         //
         //
         //
         
         double haOpen;
         if (r>0)
                haOpen  = (workHa[r-1][instanceNo+2] + workHa[r-1][instanceNo+3])/2.0;
         else   haOpen  = (open[i]+close[i])/2;
         double haClose = (open[i] + high[i] + low[i] + close[i]) / 4.0;
         double haHigh  = MathMax(high[i], MathMax(haOpen,haClose));
         double haLow   = MathMin(low[i] , MathMin(haOpen,haClose));

         if(haOpen  <haClose) { workHa[r][instanceNo+0] = haLow;  workHa[r][instanceNo+1] = haHigh; } 
         else                 { workHa[r][instanceNo+0] = haHigh; workHa[r][instanceNo+1] = haLow;  } 
                                workHa[r][instanceNo+2] = haOpen;
                                workHa[r][instanceNo+3] = haClose;
         //
         //
         //
         //
         //
         
         switch (price)
         {
            case pr_haclose:     return(haClose);
            case pr_haopen:      return(haOpen);
            case pr_hahigh:      return(haHigh);
            case pr_halow:       return(haLow);
            case pr_hamedian:    return((haHigh+haLow)/2.0);
            case pr_hamedianb:   return((haOpen+haClose)/2.0);
            case pr_hatypical:   return((haHigh+haLow+haClose)/3.0);
            case pr_haweighted:  return((haHigh+haLow+haClose+haClose)/4.0);
            case pr_haaverage:   return((haHigh+haLow+haClose+haOpen)/4.0);
            case pr_hatbiased:
               if (haClose>haOpen)
                     return((haHigh+haClose)/2.0);
               else  return((haLow+haClose)/2.0);        
         }
   }
   
   //
   //
   //
   //
   //
   
   switch (price)
   {
      case pr_close:     return(close[i]);
      case pr_open:      return(open[i]);
      case pr_high:      return(high[i]);
      case pr_low:       return(low[i]);
      case pr_median:    return((high[i]+low[i])/2.0);
      case pr_medianb:   return((open[i]+close[i])/2.0);
      case pr_typical:   return((high[i]+low[i]+close[i])/3.0);
      case pr_weighted:  return((high[i]+low[i]+close[i]+close[i])/4.0);
      case pr_average:   return((high[i]+low[i]+close[i]+open[i])/4.0);
      case pr_tbiased:   
               if (close[i]>open[i])
                     return((high[i]+close[i])/2.0);
               else  return((low[i]+close[i])/2.0);        
   }
   return(0);
}